Binary numbers toy in Erlang GS graphics

Because of popular demand, I have ported the previous example to Erlang using it's built-in GS package. Enjoy! :-D



All code and text in this post is Copyright (c) bkil.hu [also known as bkil], 2009; and is licensed under the GNU GPL v2. Refer to the standard license texts from June 1991 for exact conditions. Here is an example link: http://www.gnu.org/licenses/gpl-2.0.html

---

Here's the core (simbins.erl):

-module(simbins).
-export([radix/3, binaries/2, simbins/1]).

%% Radix conversion with LSB output.
radix(_,0,_) -> [];
radix(R,W,N) -> [N rem R | radix(R, (W-1), (N div R))].

%% A full-matrix transpose stub.
transpose([H|T]) when is_list(H) ->
    Append  = fun(V, M) -> lists:zipwith(fun(E,L) -> [E|L] end, V, M) end,
    Vector  = fun(L) -> lists:map(fun(E) -> [E] end, L) end,
    [RH|RT] = lists:reverse([H|T]),
    lists:foldl(Append, Vector(RH), RT).

%% 'binaries' is a solution to Paul R. Potts's idea.
%% Prepend `lists:reverse( ` to get MSB.
binaries(W,L) -> transpose( lists:map( fun(N)->radix(2,W,N) end, L ) ).

%% A lame math power function, but at least it's short.
pow(_,0)          -> 1;
pow(R,N) when N>0 -> R * pow(R,N-1).

simbins(W) ->
    Cols = binaries(W, lists:seq(0, pow(2,W)-1) ),
    Dbl  = lists:map(fun(S) -> S ++ lists:reverse(S) end, Cols),
    lists:reverse(Dbl) ++ Dbl.

---

Standard output text interface (textbin.erl):

-module(textbin).
-export([start/0]).
-import(simbins).

unlines(L) ->
    Strings = lists:map(fun(S)-> S ++ "\n" end, L),
    lists:append( Strings ).

toChar(0) -> $ ;
toChar(_) -> $@.

toChars(S) -> lists:map(fun toChar/1, S).

textOut(L) ->
    Strings = lists:map(fun toChars/1, L),
    io:format( unlines( Strings ) ).

start() -> textOut( simbins:simbins(5) ).

---

Graphics interface (graphbin.erl):

-module(graphbin).
-export([start/0]).
-import(simbins).

catMaybes([H|T]) when is_list(H) -> lists:append([H|T]).

put(Canvas, W, H) ->
    fun({X,Y}) ->
        X0 = W*X,  X1 = W*(X+1),
        Y0 = H*Y,  Y1 = H*(Y+1),
        gs:rectangle( Canvas, [ {bw,0}, {fill, white},
                      {coords, [{X0,Y0}, {X1,Y1}]} ]) end.

visDots([H|T]) ->
    LH = lists:seq(0,length(H)-1),
    LT = lists:seq(0,length(T)),
    Elem = fun(Y) -> fun(_,0) -> [];
                        (X,_) -> [{X,Y}] end end,
    Rows = fun(Y,Col) -> lists:zipwith(Elem(Y), LH, Col) end,
    Dots = lists:zipwith(Rows, LT, [H|T]),
    catMaybes( lists:append(Dots) ).

graphOut(DW, DH, [H|T]) ->
    WinSize = [{width,DW*length(H)}, {height,DH*length([H|T])}],
    Win     = gs:window(gs:start(), WinSize ++
                  [ {title,"Simbins"}, {keypress,true} ]),
    Canvas  = gs:canvas( Win, WinSize ++ [{bg, black}] ),
    lists:foreach( put(Canvas, DW, DH), visDots([H|T]) ),
    gs:config(Win, {map,true}),
    case getKey() of
        cancel -> cancel;
        _      -> gs:destroy(Win)
    end.

getKey() ->
    receive
        {gs, _, destroy,  _, _   } -> cancel;
        {gs, _, keypress, _, Args} -> Args
    end.

start() -> graphOut( 2, 4, simbins:simbins(6) ).